/***************************************************************
* Fuente para Povray que ilustra operaciones de cambio de escala
* giros y traslaciones.(C) Antonio Castro Snurmacher. - oct-2009
* Disponible para descarga bajo licencia Creative Commons By.
****************************************************************/

#include "colors.inc"

#declare PosCamera= <10,10,10>;
// Crearemos un objeto de tres colores. 
#declare Tricono= composite {
  cone {
     <0,0,0> 3, <6,0,0> 1
     pigment { Red }
  }
  cone {
     <0,0,0> 3, <0,6,0> 1
     pigment { Green }
  }
  cone {
     <0,0,0> 3, <0,0,6> 1
     pigment { Blue }
  }
}


camera {
  location PosCamera
  look_at <0, 0, 0>  
}

// Fuente de luz blanca
object {
  light_source {
  <0, 50, 50>
  color White
  }
}

// No necesitamos componer los ejes en un único objeto porque no vamos a manipularlos.
cylinder { 
   <-999,0,0> , <999, 0, 0>, 0.2
   pigment { Red }
}
cylinder { 
   <0,-999,0> , <0,999, 0>, 0.2
   pigment { Green }
}
cylinder { 
   <0,0,-999> , <0,0,999>, 0.2
   pigment { Blue }
}


object {
   Tricono
   #switch (clock)
      #case (1)	  
          // Nada. clock=1, el objeto ni se escala, ni se gira ni se traslada
      #break
      #case (2)
	  scale 0.25
      #break
      #case (3)
	  scale -1
      #break
      #case (4)
	  scale <0.5,2,1>   
      #break
      #case (5)
	  rotate z*25
      #break
      #case (6)
	  rotate y*25
      #break
      #case (7)
	  rotate z*45 rotate y*45
      #break
      #case (8)
	  rotate y*45 rotate z*45
      #break
      #case (9)
	  rotate z*-25  translate <-10,0,0>  
      #break
      #case (10)
	  translate <-10,0,0> rotate z*25
      #break
      #case (11)
	  rotate y*-90
      #break
      #case (12)
	  rotate y*-90 translate <0,0,-5>
      #break
      #case (13)
	 rotate y*-45 translate <0,-5,-5> 
      #break
   #end
}